Привет,
smb. Вот, смотри, какой модуль получился. Давай тогда сначала отдельно про функцию Random в типах Char и LongInt.
В типах Char функция Random делается довольно просто. Там применяется функция Chr, которая вместро числа подставляет соответствующий символ по таблице. Например Chr(80) будет равно 'P', Chr(84) будет равно 'T'. Есть также функция Ord, которая, наоборот, вместо символов подставляет соответствующие числа.
Код:
{функция не имеет параметров и просто возвращае один из 256 символов}
function RandChar : Char;
var
A : Byte;
begin
A := Random(256); {A - случайное число от 0 до 255}
RandChar := Chr(A);
end;
Насчёт типа LongInt. Ты верно заметила, что функция Random позволяет выбрать только числа, которые соответствуют типу Word.
В этом случае можно поступить следующим образом:
1) Сделать первое случайное число в пределах типа Word.
2) Сделать второе случайное число в пределах типа Word.
Оба числа будут в пределах от 0 до 65535 (или от 0000 до FFFF в 16-ой системе счисления).
3) Первое число умножить на 65536 (или на 10000 в шестнадцатеричной системе). Получится что-то вроде 450B 0000 (последние четыре цифры обязательно будут нулями, так как умножили на круглое число).
4) Прибавить к нему второе неумноженное. В результате получится число от 0000 0000 до FFFF FFFF - т.е. как раз соответствующее типу LongInt.
Получится, что мы собрали случайное число LongInt из двух случайных чисел Word, переведя цифры одного из них в более старшие разряды и приплюсовав к нему другое.
Вычисления в программе удобнее производить в шестнадцатеричном формате. Для этого перед числами ставится знак $.
Код:
{функция не имеет параметров и просто возвращает случайное число
в диапазоне типа LongInt}
function RandLongInt : LongInt;
var
A, B : LongInt;
begin
A := (Random($FFFF) + Random($2)) * $10000;
B := (Random($FFFF) + Random($2));
RandLongInt := A + B
end;
Важно отметить, что в функции Random можно ставить число не больше 65535 и в результате самое большое число, которое может получиться - это 65534, т.е. на единицу меньше. Поэтому чтобы перекрыть весть диапазон от 0000 до FFFF нужно ещё рандомно прибавлять либо 0 либо 1 (т.е. прибавлять к числу
Random($2) ).
Об отрицательных числах волноваться не надо, так как в памяти компьютера целые числа такого типа представляются таким образом, что знак определяется первой (слева) цифрой числа. Если большее или равно 8, то число отрицательной. Таким образом, например, 95A3 0010 - отрицательное, а 200A 0002 - положительное. Поэтому в данном случае числа будут и положительными, и отрицательными.
Теперь сам модуль. Он получился примерно таким.
Код:
unit Files;
interface
type
TMType = Longint;
procedure OpenAndFill(var F : Text); {открыти и заполнение}
procedure ReadFromFile(var F : Text; var V : TMType; P : Integer);
{считывание в переменную V из позиции P}
function FindInFile (var F : Text; V : TMType) : Integer;
{поиск данных соответствующих значению переменной V}
procedure CloseFile (var F : Text); {закрытие файла}
implementation
{Описание процедур и функций}
procedure OpenAndFill(var F : Text);
function RandLongInt : LongInt; {вложенная функция для случайных чисел LongInt}
var
A, B : LongInt;
begin
A := (Random($FFFF) + Random($2)) * $10000;
B := (Random($FFFF) + Random($2));
RandLongInt := A + B
end;
var
I, L : Integer;
begin
L := Random(41) + 10; {число данных в файле случайное - от 10 до 50}
Rewrite(F); {открываем файл для записи}
for I := 1 to L do
begin
Write(F, RandLongInt); {записываем случайное число}
Writeln(F); {новая строка}
end;
end;
procedure ReadFromFile(var F : Text; var V : TMType; P : Integer);
var
I : Integer;
begin
I := 1;
Reset(F); {открываем файл для чтения}
While(EOF(F) = False) and (I < P) do {спускаемся до нужной позиции или до конца файла}
begin
Readln(F);
I := I + 1;
end;
Read(F, V); {записываем данные из позиции P в переменную V}
end;
function FindInFile(var F : Text; V : TMType) : Integer;
var
A : TMType;
I : Integer;
B : Boolean; {показывает, если данные найденнны}
begin
I := 1;
B := False;
Reset(F);
While(EOF(F) = False) do {пока не дошли до конца файла}
begin
Read(F, A);
if A = V then {если данные соответствуют значению переменной V, прекратить поиск}
begin
B := True;
break;
end;
I := I + 1;
Readln(F);
end;
if B = True then FindInFile := I {вернуть функции значение номера строки}
else FindInFile := 0;
end;
procedure CloseFile (var F : Text);
begin
Close(F); {закрытие файла}
end;
begin
Randomize; {в этом модуле есть функция Randomize, в самой программе её писать будет не
нужно}
end.
Это текст программы с примером использования процедур и функций модуля.
Код:
program Prog;
uses Files;
var
V : TMType;
F : Text;
begin
Assign(F, 'C:\Pascal\textfile.txt');
OpenAndFill(F);
ReadFromFile(F, V, 10);
Writeln(V);
WriteLn(FindInFile(F,V));
CloseFile(F);
end.
Наверняка ты знаешь, но на всякий случай напомню, что имя сохраняемого файла модуля должно совпадать с именем модуля в начеле, в нашем случае Files. Он сохранится в файл Files.tbu. При использовании модуля в среде разработки Pascal в меня Options->Directories нужно указать путь к модулям.
Если нужно что-нибудь ещё, буду рад помочь. =)
-element(n-1)), вроде как.
P.S. Пришлось внести незначительные коррекции
, но в целом СУПЕР..Неожидал,что кто-то поможет
...
